Web Page - Lists and Hints

[Joerg Hamacher]

Hi again,

when using lists in a form there is the property "Hint".
Is there anything similar to this in Lists for web pages?
I like to have a hint for the column headers (because sometimes there are cryptical abbreviations used as header which need an explication).
And I need to create tooltips in every column (e.g. for showing the customer name when only the customer number is displayed) also.

How can this be managed?

Many thanks in advance and best regards,
Joerg

[JamesDuignan]

Hi Joerg,

There is not a hint property for Prim_list column headings.

however, using the columnpopup property you can make a hint for the column headers.

for example:

Code: Select all

Begin_Com Role(*EXTENDS #PRIM_WEB) Theme(#SYS_THEME<MaterialDesignBlue>) Layoutmanager(#Layout1)

Define_Com Class(#PRIM_TBLO) Name(#Layout1)
Define_Com Class(#PRIM_TBLO.Row) Name(#Layout1Row1) Displayposition(1) Parent(#Layout1)
Define_Com Class(#PRIM_TBLO.Column) Name(#Layout1Column1) Displayposition(1) Parent(#Layout1)
Define_Com Class(#PRIM_TBLO.Item) Name(#Layout1Item1) Column(#Layout1Column1) Manage(#List1) Parent(#Layout1) Row(#Layout1Row1)

Define_Com Class(#PRIM_LIST) Name(#List1) Displayposition(1) Left(0) Parent(#COM_OWNER) Tabposition(1) Top(0) Height(800) Width(1200) Hintshowofparent(False) Hinttitle('List1') Columnheaderheight(48)
Define_Com Class(#PRIM_LIST.String) Name(#Column1) Columnwidth(434) Displayposition(1) Parent(#List1) Source(#xDemoAlpha128) Columnpopup(#PopupMenu)
Define_Com Class(#PRIM_LIST.Number) Name(#Column2) Columnwidth(308) Displayposition(2) Parent(#List1) Source(#xDemoNumber) Columnpopup(#PopupMenu)


Define_Com Class(#PRIM_PPNL) Name(#PopupMenu) Height(48) Width(200)
Define_Com Class(#PRIM_EDIT) Name(#Edit) Parent(#PopupMenu) Displayposition(1) Tabposition(1) Height(48) Left(0) Top(0) Width(200)

Evtroutine Handling(#Com_owner.Initialize)

#xDemoAlpha128 := aaaaa

#xDemoNumber := 1234

Inz_List Num_Entrys(5)


Endroutine

Evtroutine Handling(#Column1.ColumnMouseEnter #Column2.ColumnMouseEnter) Com_Sender(#Sender)

Case (#Sender.name.UpperCase)

When (= 'COLUMN1')

#Edit := 'This is Column One'

When (= 'COLUMN2')

#Edit := 'This is Column Two'

Endcase

#PopupMenu.ShowPopup

Endroutine


Evtroutine Handling(#Column1.ColumnMouseLeave #Column2.ColumnMouseLeave) Com_Sender(#Sender)

#PopupMenu.ClosePopup

Endroutine


End_Com

regards,
James